examples/archived/aqua-ceramic-integration/aqua/ceramic_demo.aqua

data CeramicResult:
  ret_code: i32
  stderr: string
  stdout: string

service CeramicAdapter("service-id"):
  ceramic_request(args: []string) -> CeramicResult
  create_schema(schema: string) -> CeramicResult
  create_stream(payload: string) -> CeramicResult
  show(stream_id: string) -> CeramicResult
  state(stream_id: string) -> CeramicResult
  update(stream_id: string, payload: string) -> CeramicResult

  http_streams(url:string, port: u32, stream_id:string) -> string

-- aqua function to create stream and return stream id
func create(payload:string, node:string, service_id:string) -> string:
    on node:
        CeramicAdapter service_id
        create_res <- CeramicAdapter.create_stream(payload)
    <- create_res.stdout

-- aqua function to create stream and return CeramicResult
func create_obj(payload:string, node:string, service_id:string) -> CeramicResult:
    on node:
        CeramicAdapter service_id
        create_res <- CeramicAdapter.create_stream(payload)
    <- create_res

-- aqua function to create stream, show, update and return stream id, show and update as stdout strings
func roundtrip(payload:string, payload_two: string, node:string, service_id:string) -> string, string, string:
    on node:
        CeramicAdapter service_id
        create_res <- CeramicAdapter.create_stream(payload)                      --< return the stream_id in stdout
        show_res <- CeramicAdapter.show(create_res.stdout)                       --< use the stream_id
        update_res <- CeramicAdapter.update(create_res.stdout, payload_two)     --< update the stream
    <- create_res.stdout, show_res.stdout, update_res.stdout                    --< return the stream id, the show result, show result afer update


func http_show_stream(stream_id: string, node: string, service_id:string) -> string:
    on node:
        CeramicAdapter service_id
        res <- CeramicAdapter.http_streams("127.0.0.1", 7007, stream_id)
    <- res